home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
T-TPUG Old Monthly Disks
/
(c)tk.d64
/
phonepole
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
26KB
|
736 lines
10 CLR:OPEN2,2,0,CHR$(6)+CHR$(0):GOTO250
20 GOTO40
30 PRINTCHR$(32);CHR$(32);:Z4$=""
40 PRINT"[191][157]";:FORZL=1TO30
50 GETZ1$:GET#2,Z2$:Z3$=Z1$+Z2$:IFZ3$<>""THEN90
60 NEXT:PRINT"[191][146][157]";:FORZL=1TO30
70 GETZ1$:GET#2,Z2$:Z3$=Z1$+Z2$:IFZ3$<>""THEN90
80 NEXT:GOTO40
90 IFZ3$<>CHR$(20)THEN130
100 ZZ=LEN(Z4$):IFZZ<1THEN40
110 Z4$=LEFT$(Z4$,ZZ-1):PRINTCHR$(20);:IFZ2$=""THENPRINT#2,CHR$(20);
120 GOTO20
130 IFZ3$=CHR$(13)ANDC$<>"C"THENPRINTCHR$(32):PRINT#2,Z1$;:RETURN
140 IFZ3$=CHR$(13)ANDZ4$<>CHR$(13)+"Q"THENPRINTCHR$(32);:Z4$=""
150 IFZ3$=CHR$(13)ANDZ4$=CHR$(13)+"Q"THENC$="":PRINTCHR$(32):PRINT#2,Z1$;:RETURN
160 PRINTZ3$;:PRINT#2,Z1$;
170 Z4$=Z4$+Z3$
180 GOTO20
190 :
200 GETZ3$:PRINT#2,Z3$;:GET#2,Z2$:Z4$=Z2$+Z3$:IFZ4$=""THEN200
210 IFZ4$=CHR$(32)ORZ4$=CHR$(160)THENRETURN
220 IFZ4$="R"ORZ4$="T"ORZ4$=CHR$(13)THENRETURN
230 GOTO200
240 :
250 PRINT"[147]":POKE53280,0:POKE53281,0:GOSUB1910
260 PG$=" PURPLE, LT. BLUE, MAROON, ORANGE, RED, YELLOW, GREEN, DK. BLUE"
270 DIMPN$(42),D(42,1),CH$(16),CC$(16),P(42,9),PT$(42),C$(42),PS(42),H(42),MG(42)
280 DIM P$(2),PL(2),O(2),JT(2),M(2),CJ(2)
290 GOSUB510:PRINT"DO YOU WANT AUCTION RULE (Y OR N)";:GOSUB30:Q$=Z4$
300 IFLEFT$(Q$,1)="Y"THENAF=1
310 PRINT"WANT FREE PARKING JACKPOT OPTION ";:GOSUB30:Q$=Z4$
320 IFZ2$<>""THENZ5$="RECIEVER"
330 IFLEFT$(Q$,1)="Y"THENPF=1:FP=500
340 M(1)=1500:M(2)=1500:PL(1)=1:PL(2)=1:DV=2
350 CD$="":CR$=""
360 IFZ5$<>""THENINPUT#2,ZQ
370 IFZ5$=""THENFORZL=1TO400:NEXT:ZQ=RND(-TI):PRINT#2,ZQ:
380 X1=8:Y1=10:X2=23:Y2=10:RX=6:RY=18:TN=832:TT=886
390 E$=" [146]":RM$="HIT 'R' OR 'T'[146]"
400 PRINT"[147][159] PLEASE WAIT WHILE I SET UP."
410 FORI=1TO4:P(6+((I-1)*10),8)=100:NEXT:P(13,8)=75:P(29,8)=75
420 IFZ5$<>""THENINPUT#2,CH:INPUT#2,CC
430 IFZ5$=""THENFORZL=1TO5:NEXT:CH=INT(RND(1)*16)+1:PRINT#2,CH:
440 IFZ5$=""THENCC=INT(RND(1)*16)+1:PRINT#2,CC:
450 FORI=1TO41:FORJ=0TO1:READD(I,J):NEXT:NEXT
460 P$(1)=" PLAYER 1[146]":P$(2)=" PLAYER 2[146]"
470 FORI=1TO41:READPN$(I):NEXT:FORI=1TO41:READPT$(I):IFPT$(I)<>"P"THEN490
480 READC$(I):FORJ=1TO9:READP(I,J):NEXTJ
490 NEXTI
500 FORI=1TO16:READCH$(I):NEXT:FORI=1TO16:READCC$(I):NEXT:GOTO610
510 PRINT"[154] [170][191] [191][146][180][170][183][183][183][180][170][191] [180][170][183][183][183][180][170][183][183][208][170][183][183][183][180][170] [207][183]"
520 PRINT" [170] [191][191][146] [180][170] [180][170] [191] [180][170] [180][170][175][175][186][170] [180][170] [204]"
530 PRINT" [170] [180][170] [180][170] [191] [180][170] [180][170] [170] [180][170] [207]"
540 PRINT" [170] [180][170][175][175][175][180][170] [191][180][170][175][175][175][180][170] [170][175][175][175][180][170][175][175][175] [204][175]"
550 PRINTTAB(19);"BY"
560 PRINT" TIM BORION, SAL OEPER & R.C.DAVIS"
570 PRINT"HIT 'R' TO ROLL DICE AND 'T' FOR TRANSACTION MENU."
580 PRINT"'0' CAN BE USED TO RETURN FROM MOST SUBROUTINES"
590 PRINT:PRINT"DEVELOPED PROPERTIES MAY NOT BE TRADED.":PRINT
595 FORZL=1TO2000:NEXT
600 FORZL=1TO300:AN=PEEK(56577):IFAN AND16THENNEXT
605 RETURN
610 POKE54277,79:POKE54284,79:POKE54291,79
620 POKE54278,248:POKE54286,248:POKE54292,248
630 POKE54276,33:POKE54288,33:POKE54290,33
640 G(1)=54272:G(2)=54273:G(3)=54279:G(4)=54280:G(5)=54286:G(6)=54287
650 FORI=1TO6:POKEG(I),0:NEXT
660 POKE54296,15:IFPEEK(832)<>160THENGOSUB6900
670 GOSUB1640:FORPK=1TO2:POKED(1,PK-1),48+PK:O(PK)=D(1,PK-1):PT=PK:NEXT:GOSUB6990
680 GOSUB1940:IFR1=R2THEN680
690 PT=(R1>R2)+2
700 POKED(PL(1),0),49:POKED(PL(2),1),50
710 PT$=STR$(PT)
720 MS$="PLAYER"+PT$+" STARTS[146]"
730 X=RX:Y=RY:Z$=MS$:GOSUB1890:FORDE=1TO1500:NEXT:Z$=E$:GOSUB1890:GOTO940
740 DV=2:MF=0:JB=0
750 IFPL(PT)=41THEN850
760 JT(PT)=0
770 GOSUB1940:DF=1
780 IFDB=3THENSYSTN:GOSUB3600:SYSTT:GOSUB6990:GOTO880
790 FORM=1TODR:PL(PT)=PL(PT)+1
800 POKEO(PT),160:IFPL(PT)>40THENPL(PT)=PL(PT)-40:SYSTN:GOSUB2070:SYSTT
810 POKED(PL(PT),PT-1),48+PT
820 O(PT)=D(PL(PT),PT-1)
830 FORT=1TO50STEP6+PT:FORI=1TO6:POKEG(I),T:NEXT:NEXT
840 FORI=1TO6:POKEG(I),0:NEXT:NEXTM
850 POKED(PL(PT),PT-1),48+PT:GOSUB6990
860 SYSTN:GOSUB2140:SYSTT:GOSUB6990:IFM(PT)<0THENGOSUB6730:SYSTT
870 IFPL(PT)=11THENPOKED(41,PT-1),160:POKED(11,PT-1),48+PT
880 IFJBTHENJB=0:POKEO(PT),160:O(PT)=D(PL(PT),PT-1):GOTO790
890 IFMFTHENMF=0:POKEO(PT),160:O(PT)=D(PL(PT),PT-1):GOTO850
900 IFJETHENJE=0:POKEO(PT),160:O(PT)=D(PL(PT),PT-1):GOTO940
910 IFJFTHENJF=0:POKED(PL(PT),PT-1),48+PT:POKEO(PT),160:O(PT)=D(PL(PT),PT-1)
920 IFDBTHEN940
930 PT=3-PT
940 Z$=P$(PT):X=RX:Y=RY-1:GOSUB1890
950 Z$=RM$:X=RX:Y=RY:GOSUB1890
960 GETBC$:IFBC$<>""THEN960
970 GOSUB190:A$=Z4$
980 IFA$="T"THENSYSTN:GOSUB4580:SYSTT:GOSUB6990:GOTO940
990 Z$=E$:X=RX:Y=RY:GOSUB1890
1000 GOTO740
1010 DATA1978,1938,1974,1973,1931,1930,1968,1967,1925,1924,1922,1921
1020 DATA1959,1958,1956,1955,1953,1952,1950,1949,1944,1904
1030 DATA1824,1825,1744,1745,1664,1665,1584,1585,1505,1506,1424,1425
1040 DATA1346,1347,1264,1265,1184,1185,1104,1105
1050 DATA1029,1030,1032,1033,1035,1036,1038,1039,1081,1082,1044,1045
1060 DATA1047,1048,1130,1131,1053,1054,1096,1097
1070 DATA1217,1218,1297,1298,1377,1378,1457,1458,1536,1537,1617,1618
1080 DATA1697,1698,1777,1778,1857,1858,1906,1907
1090 DATA">GO<[155]","[155]MEDITERRANEAN AVE.[155]","[158]COMMUNITY CHEST[155]","[155]BALTIC AVE.[155]"
1100 DATA"[154]INCOME TAX[155]"
1110 DATA"[152]READING R.R.[155]","[159]ORIENTAL AVE.[155]","[150]CHANCE[155]","[159]VERMONT AVE.[155]"
1120 DATA"[159]CONNECTICUT AVE.[155]"
1130 DATA"[150]JUST VISITING[155]","[156]ST.CHARLES PLACE[155]","[153]ELECTRIC COMPANY[155]","[156]STATES AVE.[155]"
1140 DATA"[156]VIRGINIA AVE.[155]","[152]PENNSYLVANIA R.R.[155]","[129]ST. JAMES PLACE[155]"
1150 DATA"[158]COMMUNITY CHEST[155]"
1160 DATA"[129]TENNESSEE AVE.[155]","[129]NEW YORK AVE.[155]","[149]FREE PARKING[155]","KENTUCKY AVE.[155]"
1170 DATA"[150]CHANCE[155]","INDIANA AVE.[155]","ILLINOIS AVE.[155]","[152]B & O R.R.[155]"
1180 DATA"[158]ATLANTIC AVE.[155]"
1190 DATA"[158]VENTNOR AVE.[155]","[153]WATER WORKS[155]","[158]MARVIN GARDENS[155]","[150]GO[155] [154]TO[155] JAIL[155]"
1200 DATA"PACIFIC AVE.[155]"
1210 DATA"N. CAROLINA AVE.[155]","[158]COMMUNITY CHEST[155]","PENNSYLVANIA AVE.[155]"
1220 DATA"[152]SHORT LINE[155]"
1230 DATA"[150]CHANCE[155]","PARK PLACE[155]","[154]LUXURY TAX[155]","BOARDWALK[155]","[150]IN JAIL[155]"
1240 DATAGO,P,PURPLE,60,2,10,30,90,160,250,30,50,CC,P,PURPLE,60,4,20,60,180,320
1250 DATA450,30,50,IT,RR,P,LT. BLUE,100,6,30,90,270,400,550,50,50,CH,P,LT. BLUE
1260 DATA 100,6,30,90,270,400,550,50,50,P,LT. BLUE,120,8,40,100,300,450,600,60,50
1270 DATAJV,P,MAROON,140,10,50,150,450,625,750,70,100,U,P,MAROON,140,10,50,150,450
1280 DATA625,750,70,100,P,MAROON,160,12,60,180,500,700,900,80,100,RR
1290 DATAP,ORANGE,180,14,70,200,550,750,950,90,100,CC,P,ORANGE
1300 DATA 180,14,70,200,550,750,950,90,100
1310 DATAP,ORANGE,200,16,80,220,600,800,1000,100,100,FP,P,RED
1320 DATA 220,18,90,250,700,875
1330 DATA1050,110,150,CH,P,RED,220,18,90,250,700,875,1050,110,150,P,RED,240
1340 DATA 20,100,300
1350 DATA750,925,1100,120,150,RR,P,YELLOW,260,22,110,330,800,975,1150,130,150
1360 DATA P,YELLOW,260
1370 DATA22,110,330,800,975,1150,130,150,U,P,YELLOW,280,24,120,360,850,1025,1200
1380 DATA 140
1390 DATA150,GTJ,P,GREEN,300,26,130,390,900,1100,1275,150,200,P,GREEN
1400 DATA 300,26,130,390,900
1410 DATA1100,1275,150,200,CC,P,GREEN,320,28,150,450,1000,1200,1400
1420 DATA 160,200,RR,CH
1430 DATAP,DK. BLUE,350,35,175,500,1100,1300,1500,175,200,LT,P,DK. BLUE
1440 DATA 400,50,200,600,1400
1450 DATA1700,2000,200,200,IJ
1460 DATA PAY POOR TAX $15,GO DIRECTLY TO JAIL,ADVANCE TO GO(COLLECT $200)
1470 DATA YOUR BUILDING AND LOAN MATURES COLLECT $150
1480 DATA ADVANCE TOKEN TO NEAREST R.R. $ PAY OWNER TWICE RENT
1490 DATAADVANCE TO ILLINOIS AVE.,BANK PAYS YOU DIVIDEND OF $50
1500 DATAGET OUT OF JAIL FREE,PAY EACH PLAYER $50,ADVANCE TO ST. CHARLES PLACE
1510 DATATAKE A RIDE ON THE READING,GO BACK THREE SPACES,ADVANCE TO BOARDWALK
1520 DATAMAKE GENERAL REPAIRS $25 FOR EACH HOUSE$100 FOR EACH HOTEL
1530 DATA ADVANCE TOKEN TO NEAREST R.R. $ PAY OWNER TWICE RENT
1540 DATA ADVANCE TOKEN TO NEAREST UTILITY ROLL DICE & PAY 10*# SHOWN
1550 DATA GET OUT OF JAIL FREE,GO TO JAIL,ADVANCE TO GO(COLLECT $200)
1560 DATA FROM SALE OF STOCK YOU GET $45,COLLECT $50 FROM EVERY PLAYER
1570 DATA RECEIVE FOR SERVICES $25,PAY SCHOOL TAX OF $150,TAX REFUND COLLECT $20
1580 DATA ASSESSED FOR REPAIRS $40 PER HOUSE $115 PER HOTEL
1590 DATA YOU HAVE WON SECOND PRIZE IN A BEAUTY CONTEST COLLECT $10
1600 DATA YOU INHERIT $100,XMAS FUND MATURES COLLECT $100,PAY HOSPITAL $100
1610 DATA BANK ERROR IN YOUR FAVOR COLLECT $200,DOCTORS FEE PAY $50
1620 DATA LIFE INSURANCE MATURES COLLECT $100
1630 GOTO6890
1640 PRINT"[147][149] [160][155][165][160][160][165][160][160][165][160][160][165][160][160][152][191][191][191][155][165][160][160][165] [165][153]WW[155][165][160][160][150][165]GTJ[146]"
1650 PRINT"[149][160]FP[160][155][165][160][160][165][150]?[155][160][165][160][160][165][160][160][152][165][160][160][155][165][160][160][165][160] [165][153][176][177][155][165][160][160][154][165] [146]"
1660 PRINT"[149] [160] [155][165][160][160] [160][160][165] [152]B&O[158][165] [165][160][160][155][165][160][160][158] [160][160][165][197][215] [155][146]"
1670 PRINT"[163][163][163][129] [155][207][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163] [155][163][163][163][146]"
1680 PRINT" [129] [155][165] [206][205] [155][160] [146]"
1690 PRINT"[163][163][163][129][163][155][165] [158][206] [155][205] 1- [163][155][163][163][163][146]"
1700 PRINT" [129] [155][165][206][158]C C[155][206] [155] [146]"
1710 PRINT"[163][163][163][163][165][205][158] [206][155] 2- [207][163][163][163][146]"
1720 PRINT"[158]CC[155] [165] [205][206] [158]CC[155] [146]"
1730 PRINT"[163][163][163][129] [155][165] [164][164][164] [164][164][164] [155][163][163][163][146]"
1740 PRINT" [129] [155][165] [167] [155][165] [167] [155][165] [155] [146]"
1750 PRINT"[152][191]PR[191][155][165] [167] [155][165] MONOPOLE[155] [167] [155][165] [167][152][191]SL[191][146]"
1760 PRINT"[191] [191][155][165] [167] [155][165] CBM-64[155] [167] [155][165] [167][152][191] [191][155][146]"
1770 PRINT"[163][163][163][156] [155][165] [163][163][163] [163][163][163] [207][163][163][163][146]"
1780 PRINT" [156] [155][165] [165][150]?[155] [146]"
1790 PRINT"[163][163][163][156][163][155][165] [206][205] [155][163][163][163][146]"
1800 PRINT" [156] [155][165] [150][206] [155][205] [155] [146]"
1810 PRINT"[163][153]EC[155][163][165] [206][150]???[155][206] [154]TAX[155][163][146]"
1820 PRINT" [165] [205][150] [206][155] [165] [146]"
1830 PRINT"[163][163][163][156] [155][165] [205][206] [155][163][163][163][146]"
1840 PRINT" [156] [155][165] [155] [146]"
1850 PRINT"[150][163][155][207][163][163][159] [165] [155][207][163][163][159] [152][207]RR[155][207][163][163][146] [207][163][163][146] [207][163][163][163][146]"
1860 PRINT"[150] [155][165] [165] [165] [165][150]?[155][160][165][160][160][152][165][160][160][155][165][160][160][165][160][160][165] [165] [165]GO [146]"
1870 PRINT"[150] [163][163][163][155][165] [165] [165] [165] [152][191][191][191][154]TAX[155][165] [165][158]CC[155][165] [165]_[192] [146]"
1880 RETURN
1890 PRINT"[155]";LEFT$(CR$,X);LEFT$(CD$,Y);Z$;""
1900 RETURN
1910 DC$(1)=" [157][157][157] [209] [157][157][157] [146]":DC$(2)=" [209][157][157][157] [157][157][157][209] [146]"
1920 DC$(3)="[209] [157][157][157] [209] [157][157][157] [209][146]":DC$(4)="[209] [209][157][157][157] [157][157][157][209] [209][146]"
1930 DC$(5)="[209] [209][157][157][157] [209] [157][157][157][209] [209][146]":DC$(6)="[209] [209][157][157][157][209] [209][157][157][157][209] [209][146]":RETURN
1940 CT=0
1950 IFZ5$<>""THENINPUT#2,R1:INPUT#2,R2
1960 IFZ5$=""THENFORZL=1TO5:NEXT:R1=INT(RND(1)*6)+1:PRINT#2,R1:
1970 IFZ5$=""THENR2=INT(RND(1)*6)+1:PRINT#2,R2:
1980 DR=R1+R2
1990 FORI=1TO6:POKEG(I),DR*10:NEXT
2000 PRINT"";LEFT$(CR$,X1);LEFT$(CD$,Y1);DC$(R1)
2010 PRINT"";LEFT$(CR$,X2);LEFT$(CD$,Y2);DC$(R2)
2020 FORI=1TO6:POKEG(I),0:NEXT
2030 CT=CT+1:IFCT<7THENFORDELAY=1TO75:NEXT:GOTO1950
2040 IFR1=R2THENDB=DB+1:GOTO2060
2050 DB=0
2060 RETURN
2070 PRINT"[147]":PRINT
2080 PRINT" COLLECT $200 AS YOU PASS [172][162][172][187][157][157][157][157][157][188][190][188][190][146]"
2090 M(PT)=M(PT)+200:PRINT:PRINT:PRINT
2100 PRINT"HIT SPACE TO CONTINUE[146]"
2110 GETW$:IFW$<>""THEN2110
2120 GOSUB190:K$=Z4$
2130 RETURN
2140 POKE198,0:PT$=PT$(PL(PT))
2150 IFPT$="P"THEN2270
2160 IFPT$="RR"THEN2770
2170 IFPT$="GO"THENRETURN
2180 IFPT$="U"THEN3130
2190 IFPT$="FP"THEN3460
2200 IFPT$="JV"THENRETURN
2210 IFPT$="GTJ"THEN3600
2220 IFPT$="IT"THEN3710
2230 IFPT$="LT"THEN3690
2240 IFPT$="CC"THEN3730
2250 IFPT$="CH"THEN3970
2260 IFPT$="IJ"THEN4380
2270 PRINT"[147]";TAB(15);"TITLE DEED"
2280 IFGFTHEN2320
2290 PRINT" PLAYER"PT
2300 PO=3-PT
2310 PL=PL(PT):P7=PT
2320 PRINTTAB(20-(LEN(PN$(PL))-1)/2)"";PN$(PL)"[146]"
2330 PRINTLEFT$(PN$(PL),1):QR=PEEK(646):POKE53280,QR:PRINT"[145][145]"
2340 PRINT
2350 PRINT" RENT $";P(PL,2)
2360 PRINT" WITH 1 HOUSE $";P(PL,3)
2370 PRINT" WITH 2 HOUSES ";P(PL,4)
2380 PRINT" WITH 3 HOUSES ";P(PL,5)
2390 PRINT" WITH 4 HOUSES ";P(PL,6)
2400 PRINT" WITH HOTEL $";P(PL,7)
2410 PRINT
2420 PRINT" MORTAGE VALUE $";P(PL,8)
2430 PRINT" HOUSES COST $";P(PL,9);"EACH"
2440 PRINT" HOTELS, $";P(PL,9);". PLUS 4 HOUSES"
2450 IFGFTHENPRINT:PRINT:GOSUB2100:POKE53280,0:RETURN
2460 PRINT:FORI=1TO41:IFC$(PL)=C$(I)ANDI<>PLTHENGOSUB2480
2470 NEXT:GOTO2500
2480 IFPS(I)THENPRINT" "PN$(I)" OWNED BY PLAYER #"PS(I):RETURN
2490 PRINT" "PN$(I)" STILL FOR SALE.":RETURN
2500 PRINT
2510 IFMG(PL)=1THENPRINT" MORTAGED FOR $"P(PL,8)
2520 PRINT" COST $";P(PL,1)
2530 IFPS(PL)=0THEN2580
2540 PRINT" OWNED[146] BY PLAYER"PS(PL):IFH(PL)THENPRINT"WITH";
2550 IFH(PL)<5THENPRINTH(PL)"HOUSES."
2560 IFH(PL)=5THENPRINT" A HOTEL"
2570 GOTO2640
2580 PRINT" YOU HAVE $";M(P7)
2590 PRINT" DO YOU WISH TO BUY THIS PROPERTY";:PRINT" [191][157][157][157]";:GOSUB30:A$=Z4$
2600 A$=LEFT$(A$,1)
2610 IFA$="N"THEN2700
2620 IFA$<>"Y"THENPRINT"[145][145]":GOTO2590
2630 PRINT" OK YOU BOUGHT ";PN$(PL)"":M(P7)=M(P7)-P(PL,1):PS(PL)=PT:GOTO2690
2640 OW=P(PL,H(PL)+2):IFPS(PL)=PTTHEN2690
2650 IFMG(PL)THEN2690
2660 P5=PO:P6=PS(PL):GOSUB2710:IFOATHENIFH(PL)=0THENOW=OW*2
2670 M(PT)=M(PT)-OW:M(PS(PL))=M(PS(PL))+OW:PRINT" YOU OWE $";OW
2680 M(PS(PL))=M(PS(PL))+OW
2690 GOSUB2100:POKE53280,0:RETURN
2700 GOSUB6570:GOTO2690
2710 MG=0:OA=0:PC=0:FORI=1TO41:IFC$(PL)=C$(I)ANDPS(I)=P5THENPC=PC+1:IFMG(I)THENMG=MG
2720 NEXT
2730 IFPC=2ANDC$(PL)="PURPLE"THENOA=1:RETURN
2740 IFPC=2ANDC$(PL)="DK. BLUE"THENOA=1:RETURN
2750 IFPC=3THENOA=1:RETURN
2760 RETURN
2770 PRINT"[147]":PL=PL(PT)
2780 PRINT"PLAYER"PT
2790 PRINT" [150][216][152] [172][146]"
2800 PRINT" [146]"
2810 PRINT" [206][149][215] [215]"
2820 PRINT
2830 PRINTTAB(20-LEN(PN$(PL))/2)"";PN$(PL)"[146]"
2840 POKE54276,129:POKE54288,17:POKE54290,17
2850 KO=129:FORT=1TO2:FORI=1TO6:POKEG(I),KO:NEXT:FORDL=1TO400:NEXT
2860 FORI=1TO6:POKEG(I),0:NEXT:FORDL=1TO60:NEXT:NEXT
2870 POKE54276,33:POKE54288,33:POKE54290,33
2880 PRINT:PRINT"RENT $25"
2890 PRINT"IF 2 R.R.'S ARE OWNED 50"
2900 PRINT"IF 3 R.R.'S ARE OWNED 100"
2910 PRINT"IF 4 R.R.'S ARE OWNED 200"
2920 PRINT
2930 PRINT"MORTAGE VALUE $100"
2940 PRINT:IFMG(PL)=1THENPRINT"MORTAGED FOR $100":GOTO3120
2950 PRINT"COST $200"
2960 PRINT:FORI=1TO41:IFPT$(I)="RR"THENGOSUB2980
2970 NEXT:GOTO3000
2980 IFPS(I)THENPRINTPN$(I)" OWNED BY PLAYER #";PS(I):RETURN
2990 PRINTPN$(I)" STILL FOR SALE.":RETURN
3000 IFPS(PL)THENPRINT"OWNED[146] BY PLAYER#";PS(PL):GOTO3080
3010 PRINT"YOU HAVE $"M(PT)
3020 PRINT"DO YOU WISH TO BUY IT";:PRINT" [191][157][157][157]";:GOSUB30:B$=Z4$:B$=LEFT$(B$,1)
3030 IFB$="N"THENGOSUB6570:GOTO3120
3040 IFB$<>"Y"THENPRINT"[145][145]":GOTO3020
3050 M(PT)=M(PT)-200:PS(PL)=PT
3060 PRINT"OK YOU BOUGHT IT"
3070 GOTO3120
3080 OW=0:O7=0
3090 IFPS(PL)=PTTHEN3120
3100 OW=25:FORI=6TO36STEP10:IFPT$(I)="RR"ANDPS(I)=PS(PL)THENOW=OW*2
3110 NEXT:OW=OW/DV:PRINT"YOU OWE $";OW:M(PT)=M(PT)-OW:M(PS(PL))=M(PS(PL))+OW
3120 GOSUB2100:RETURN
3130 PRINT"[147]"
3140 PRINT"PLAYER"PT
3150 PRINT" [158][206][163][205] [152][215][209][215] "
3160 PRINT" [158][205][150]^[158][206] [152][171][192][177][192][192][192][201] "
3170 PRINT" [158][165][165] [152][171][192][192][192][192][201][200] "
3180 PRINT" [166] [173][189] ":PRINT
3190 PL=PL(PT)
3200 PRINTTAB(20-LEN(PN$(PL))/2)"";PN$(PL)"[146]"
3210 PRINT:PRINT"IF ONE 'UTILITY IS OWNED PAY 4 TIMES THEAMOUNT SHOWN ON DICE"
3220 PRINT
3230 PRINT"IF BOTH OWNED PAY 10 [214] AMOUNT ON DICE"
3240 IFZ5$<>""THENINPUT#2,D1:INPUT#2,D2
3250 IFZ5$=""THENFORZL=1TO5:NEXT:D1=INT(RND(1)*6)+1:PRINT#2,D1:
3260 IFZ5$=""THEND2=INT(RND(1)*6)+1:PRINT#2,D2:
3270 IFDFTHEND1=R1:D2=R2
3280 PRINT:PRINT"MORTAGE VALUE $75":PRINT
3290 IFMG(PL)=1THENPRINT"MORTAGED FOR $75":GOTO3450
3300 IFPS(42-PL)THENPRINTPN$(42-PL)" OWNED BY PLAYER"PS(42-PL):GOTO3320
3310 PRINTPN$(42-PL)" STILL FOR SALE."
3320 PRINT:IFPS(PL)THENPRINT"OWNED[146] BY PLAYER#";PS(PL):GOTO3400
3330 PRINT"YOU HAVE $"M(PT)
3340 PRINT"DO YOU WISH TO BUY IT [191][157][157][157]";:GOSUB30:B$=Z4$:B$=LEFT$(B$,1)
3350 IFB$="N"THENGOSUB6570:GOTO3450
3360 IFB$<>"Y"THENPRINT"[145][145]":GOTO3340
3370 PRINT"OK YOU BOUGHT ";PN$(PL)""
3380 M(PT)=M(PT)-150
3390 PS(PL)=PT:GOTO3450
3400 IFPS(PL)=PTTHEN3450
3410 PRINT"DICE SHOW"D1"AND"D2"."
3420 MT=4:IFPS(13)=PS(PL)ANDPS(29)=PS(PL)THENMT=10
3430 IFDF=0THENMT=10
3440 OW=MT*(D1+D2):PRINT"YOU OWE $";OW:M(PT)=M(PT)-OW:M(PS(PL))=M(PS(PL))+OW
3450 MT=0:GOSUB2100:RETURN
3460 PRINT"[147]"
3470 PRINT" [129]FREE
3480 [153]" (null)LENLENLENLENLENRIGHT$"
3490 [153]" PEEK OPENORTAN^ LEFT$
3500 PRINT" [221] [159][173][192][189] [221]
3510 [153]" LEFT$ VERIFY(null)LENRIGHT$ PEEK
3520 PRINT" [213][192][189] [149][194][152][209][149][200] [173][192][201]
3530 [153]" (null) VERIFYMID$ASC(null) (null)
3540 PRINT" [173][192][152][168][192][192][192][192][192][152][168][192][189]
3550 [153]" PRINT#SPC( SPC(
3560 PRINT:PRINT" [129]PARKING":PRINT
3570 IFPF=0THENGOSUB2100:RETURN
3580 PRINT:PRINT" YOU GET THE FREE PARKING"
3590 PRINT" JACKPOT OF $"FP"!":M(PT)=M(PT)+FP:FP=0:PRINT:GOSUB2100:RETURN
3600 PRINT"[147]";TAB(15);"GO TO JAIL"
3610 IFDB=3THENPRINT:PRINT" FOR ROLLING DOUBLES 3 TIMES IN A ROW!":PRINT
3620 PRINTTAB(16);"[151][176][178][178][178][178][178][178][174]":FORI=1TO5:PRINTTAB(16);"[221][221][221][221][221][221][221][221]":NEXT
3630 PRINTTAB(16);"[173][177][177][177][177][177][177][189]":PRINT:PL(PT)=41:JF=1:DB=0
3640 FORKO=1TO3:FORT=60TO110STEP1.7:FORI=1TO6:POKEG(I),T:NEXT:NEXT
3650 FORDL=1TO10:NEXT
3660 FORT=110TO60STEP-1.7:FORI=1TO6:POKEG(I),T:NEXT:NEXT:NEXT
3670 FORI=1TO6:POKEG(I),0:NEXT
3680 PRINT"";:GOSUB2100:RETURN
3690 PRINT"[147]";TAB(15);"LUXURY TAX":PRINT:PRINTTAB(16);"PAY $75"
3700 PRINT:PRINT:PRINT:M(PT)=M(PT)-75:FP=FP+75:GOSUB2100:RETURN
3710 PRINT"[147]";TAB(15);"INCOME TAX":PRINT:PRINTTAB(16);"PAY $200"
3720 PRINT:PRINT:PRINT:M(PT)=M(PT)-200:FP=FP+200:GOSUB2100:RETURN
3730 CC=CC+1:IFCC>16THENCC=CC-16
3740 PO=3-PT:CC$=CC$(CC):IFCC=1ANDCJ(1)THENCC=CC+1:CC$=CC$(CC)
3750 PRINT"[147] [158]COMMUNITY CHEST":PRINTCC$""
3760 IFCC=1THENCJ(1)=PT
3770 IFCC=2THENGOSUB2100:GOTO3600
3780 IFCC=3THENPL(PT)=1:MF=1:GOSUB2100:GOSUB2070:RETURN
3790 IFCC=4THENM(PT)=M(PT)+45
3800 IFCC=5THENM(PT)=M(PT)+50:M(PO)=M(PO)-50
3810 IFCC=6THENM(PT)=M(PT)+25
3820 IFCC=7THENM(PT)=M(PT)-150:FP=FP+150
3830 IFCC=8THENM(PT)=M(PT)+20
3840 IFCC=9THENGOSUB3930
3850 IFCC=10THENM(PT)=M(PT)+10
3860 IFCC=11THENM(PT)=M(PT)+100
3870 IFCC=12THENM(PT)=M(PT)+100
3880 IFCC=13THENM(PT)=M(PT)-100
3890 IFCC=14THENM(PT)=M(PT)+200
3900 IFCC=15THENM(PT)=M(PT)-50
3910 IFCC=16THENM(PT)=M(PT)+100
3920 GOSUB2100:RETURN
3930 YP=0:FORI=1TO40
3940 IFPS(I)=(PT)ANDH(I)<5THENYP=YP+(40*H(I))
3950 IFPS(I)=(PT)ANDH(I)=5THENYP=YP+115
3960 NEXT:PRINT"YOU PAY $"YP:M(PT)=M(PT)-YP:FP=FP+YP:RETURN
3970 CH=CH+1:IFCH>16THENCH=CH-16
3980 PO=3-PT:CH$=CH$(CH):IFCH=8ANDCJ(2)THENCH=CH+1:CH$=CH$(CH)
3990 PRINT"[147] [150]? ? CHANCE ? ?":PRINTCH$""
4000 IFCH=1THENM(PT)=M(PT)-15:FP=FP+15
4010 IFCH=2THENGOSUB2100:GOTO3600
4020 IFCH=3THENPL(PT)=1:MF=1:GOSUB2100:GOSUB2070:RETURN
4030 IFCH=4THENM(PT)=M(PT)+150
4040 IFCH=5THENGOSUB4170:MF=1
4050 IFCH=6THENGOSUB4210:MF=1
4060 IFCH=7THENM(PT)=M(PT)+50
4070 IFCH=8THENCJ(2)=PT
4080 IFCH=9THENM(PT)=M(PT)-50:M(PO)=M(PO)+50
4090 IFCH=10THENGOSUB4230:MF=1
4100 IFCH=11THENGOSUB4250:MF=1
4110 IFCH=12THENPL(PT)=PL(PT)-3:MF=1
4120 IFCH=13THENGOSUB4270:MF=1
4130 IFCH=14THENGOSUB4290
4140 IFCH=15THENGOSUB4170:MF=1
4150 IFCH=16THENGOSUB4330:MF=1
4160 GOSUB2100:RETURN
4170 PL(PT)=PL(PT)+1:IFPL(PT)>40THENGOSUB7060:PL(PT)=PL(PT)-40
4180 IFPT$(PL(PT))="RR"THEN4200
4190 GOTO4170
4200 DV=1:RETURN
4210 IFPL(PT)>25THENGOSUB7060
4220 PL(PT)=25:RETURN
4230 IFPL(PT)>12THENGOSUB7060
4240 PL(PT)=12:RETURN
4250 IFPL(PT)>6THENGOSUB7060
4260 PL(PT)=6:RETURN
4270 PL(PT)=40:RETURN
4280 RETURN
4290 DF=0:YP=0:FORI=1TO40
4300 IFPS(I)=(PT)ANDH(I)<5THENYP=YP+(25*H(I))
4310 IFPS(I)=(PT)ANDH(I)=5THENYP=YP+100
4320 NEXT:PRINT"YOU PAY $"YP:M(PT)=M(PT)-YP:FP=FP=YP:RETURN
4330 PL(PT)=PL(PT)+1
4340 IFPL(PT)>40THENGOSUB7060:PL(PT)=PL(PT)-40
4350 IFPT$(PL(PT))="U"THEN4370
4360 GOTO4330
4370 MF=1:RETURN
4380 PRINT"[147]"
4390 JT(PT)=JT(PT)+1
4400 PRINT"PLAYER #"PT"IS IN JAIL"
4410 PRINT:PRINT"YOU HAVE BEEN IN"JT(PT)"TURNS"
4420 PRINT"YOU MAY: 1. PAY $50"
4430 PRINT" 2. USE A 'GET OUT OF JAIL FREE CARD."
4440 PRINT" 3. TRY TO ROLL DOUBLES."
4450 PRINT:PRINT"CHOICE";:GOSUB30:I=VAL(Z4$):IFI<1ORI>3THEN4450
4460 IFI=1THENM(PT)=M(PT)-50:FP=FP+50:PL(PT)=11:GOSUB2100:JE=1:RETURN
4470 IFI=2ANDCJ(1)=PTTHENCJ(1)=0:PL(PT)=11:GOSUB2100:JE=1:RETURN
4480 IFI=2ANDCJ(2)=PTTHENCJ(2)=0:PL(PT)=11:GOSUB2100:JE=1:RETURN
4490 IFI=2THENPRINT"YOU DON'T HAVE A CARD":GOTO4450
4500 IFI=3THENGOSUB1940:IFDBTHEN4560
4510 PRINT"YOU DIDN'T ROLL DOUBLES."
4520 IFJT(PT)>2THENPRINT"YOU MUST PAY THE $50":M(PT)=M(PT)-50:PL(PT)=11:JB=1
4530 IFJT(PT)>2THENGOSUB2100:FP=FP+50:RETURN
4540 GOSUB2100:RETURN
4550 IFPL(PT)=11THENGOSUB2100:JE=1:RETURN
4560 PRINT"YOU MADE IT OUT!!!":PL(PT)=11:GOSUB2100:JB=1:DB=0:RETURN
4570 GOTO6730
4580 PRINT"[147]":IFPFTHENPRINT"MONEY IN FREE PARKING JACKPOT $";FP
4590 PRINT"PLAYER 1 HAS $";M(1):PRINT"PLAYER 2 HAS $";M(2)
4600 PRINT:PRINT"PLAYER";PT"UP."
4610 PRINT:PRINT:PRINTTAB(15);"OPTIONS"
4620 PRINT
4630 PRINT" R=REVIEW PROPERTIES"
4640 PRINT" L=LIST ALL PROPERTIES"
4650 PRINT" B=BUILD HOUSES/HOTELS"
4660 PRINT" S=SELL PROPERTIES TO OTHER PLAYER"
4670 PRINT" M=MORTAGE PROPERTIES(SELL HOUSES)"
4680 PRINT" D=DISPLAY TITLE DEEDS"
4690 PRINT" Q=RETURN TO GAME"
4700 PRINT" C=CHAT MODE (Q ALONE TO EXIT)"
4710 PRINT" XX=END GAME":PRINT
4720 PRINT"CHOICE [191][157][157][157]";:GOSUB30:C$=Z4$
4730 IFC$="[191]"THEN4720
4740 IFC$="R"THENGOSUB4840
4750 IFC$="L"THENGOSUB5010
4760 IFC$="B"THENGOSUB5160
4770 IFC$="S"THENGOSUB5610
4780 IFC$="M"THENGOSUB5970
4790 IFC$="D"THENGOSUB7030
4800 IFC$="Q"THENRETURN
4810 IFC$="C"THENPRINT"CHAT-";:GOSUB30
4820 IFC$="XX"THEN6810
4830 GOTO4580
4840 PRINT"FOR WHICH PLAYER (1 OR 2)";:GOSUB30:PN=VAL(Z4$)
4850 IFPN<1ORPN>2THEN4840
4860 PRINT"[147]"
4870 PRINTTAB(6)"PROPERTIES FOR PLAYER ";PN
4880 PRINT
4890 FORI=1TO40:PO$="":IFPS(I)=PNTHENPRINTPN$(I);
4900 IFPS(I)<>PNTHEN4970
4910 IFPT$(I)<>"P"THEN4950
4920 PRINTSPC(20-(LEN(PN$(I))-2));" -";:IFH(I)<5THENPO$=STR$(H(I))+" HS"
4930 IFH(I)=5THENPO$=" HOTEL[146]"
4940 PO$=PO$+"/$"+MID$(STR$(P(I,H(I)+2)),2)
4950 IFMG(I)=1THENPO$="- MORTAGED"
4960 PRINTPO$
4970 NEXT
4980 PRINT:IFCJ(1)=PNORCJ(2)=PNTHENPRINT"GET OUT OF JAIL FREE CARD."
4990 PRINT"PLAYER"PN"HAS $";M(PN)
5000 PRINT:GOSUB2100:RETURN
5010 PRINT"[147]"
5020 TT$="NAME OWNER/[157][157][157][157][157][157]#HOUSES":PRINTTT$
5030 FORK=1TO40:IFPT$(K)<>"P"ANDPT$(K)<>"RR"ANDPT$(K)<>"U"THEN5120
5040 PRINTPN$(K)"";TAB(21);
5050 PRINTTAB(33)
5060 P$=STR$(PS(K)):PP$=MID$(STR$(H(K)),2):IFH(K)>4THENPP$="H"
5070 IFPT$(K)<>"P"THENPP$="X"
5080 IFMG(K)THENPP$="MG[146]"
5090 P$=P$+" -"+PP$
5100 IFPS(K)=0THENP$=" NONE"
5110 PRINTP$
5120 IFK=20THENPRINT:GOSUB2100:PRINT"[147]":PRINTTT$
5130 NEXTK
5140 PRINT:GOSUB2100
5150 RETURN
5160 PRINT"[147]"
5170 HO=0
5180 PRINT" ON WHICH GROUP":PRINTPG$
5190 PRINT
5200 PRINT"WHICH COLOR";:GOSUB30:C$=Z4$
5210 FORI8=1TO41:IFC$=LEFT$(C$(I8),LEN(C$))THENPL=I8:C$=C$(I8):GOTO5240
5220 NEXTI8
5230 PRINT"ILLEGAL GROUP":GOTO5200
5240 P7=PT
5250 P5=P7:GOSUB2710:IFMGTHENOA=0
5260 IFOATHEN5290
5270 PRINT"SORRY YOU EITHER DON'T OWN ALL THE PROP-ERTY IN THAT GROUP OR SOME";
5280 PRINT" IS MORTAGED.":GOSUB2100:RETURN
5290 PRINT" PROPERTY NAME # OF HOUSES(5=HOTEL)"
5300 HS=0:FORI=PLTOPL+4:IFC$=C$(I)THENPRINTPN$(I)"";TAB(30);H(I):HS=HS+H(I)
5310 NEXT
5320 PRINT:PRINT"HOUSES FOR THIS GROUP COST $"P(PL,9)"EACH"
5330 PRINT"HOTELS COST $"P(PL,9)"+ 4 HOUSES OR $";(P(PL,9)*5)
5340 PRINT
5350 PRINT"YOU HAVE $"M(PT)
5360 PRINT"HOTELS AUTOMATICALLY ADDED AFTER 4TH HOUSE"
5370 PRINT"HOW MANY HOUSES DO YOU WANT TO BUY (MAX=";:MX=((5*PC)-HS):PRINTMX")"
5380 GOSUB30:HN=VAL(Z4$):IFHN>MXTHENGOTO5370
5390 H7=INT(HN/PC):H8=HN-(H7*PC)
5400 IFM(P7)<(HN*P(PL,9))THENPRINT"YOU DON'T HAVE ENOUGH MONEY!":GOTO5370
5410 IFHN=0THENPRINT"OK":GOSUB2100:RETURN
5420 M(P7)=M(P7)-(HN*P(PL,9)):FORE=PLTOPL+4:IFC$=C$(E)THENH(E)=H(E)+H7
5430 NEXT
5440 IFH8THEN5460
5450 GOTO5600
5460 PRINT"YOU HAVE"H8"HOUSES LEFT OVER"
5470 PRINT:F1=0:FORF=PLTOPL+4:IFC$=C$(F)THENF1=F1+1:PRINTF1,PN$(F);" "H(F)
5480 NEXT:PRINT:FORG=1TOH8
5490 PRINT"WHERE DO YOU WANT HOUSE #"G;
5500 GOSUB30:HL=VAL(Z4$):IFHL=HOTHENPRINT"CAN'T":GOTO5490
5510 F2=0:F1=0:F9=0
5520 FORF=PLTOPL+3:IFC$=C$(F)THENF1=F1+1:IFF1=HLTHENF9=F
5530 NEXTF
5540 IFF9=0THENPRINT"NO SUCH NUMBER":GOTO5490
5550 H2=0:FORF=PLTOPL+3:IFC$=C$(F)THENIFH(F9)>H(F)THENH2=H2+1
5560 NEXT
5570 IFH2THENPRINT"ILLEGAL DISTRIBUTION OF HOUSES!":GOTO5490
5580 HO=HL:H(F9)=H(F9)+1
5590 NEXTG
5600 PRINT"DONE":GOSUB2100:RETURN
5610 PRINT"WHAT PLAYER HAS A PROPERTY TO SELL";:GOSUB30:P1=VAL(Z4$)
5620 IFP1=0THENGOSUB2100:RETURN
5630 P2=P1+1:IFP2>2THENP2=P2-2
5640 PRINT"IS IT A PROPERTY";:GOSUB30:Q$=Z4$:IFLEFT$(Q$,1)="N"THEN5850
5650 PRINT"IN WHAT COLOR GROUP":PRINTPG$
5660 PRINT:PRINT"WHICH";:GOSUB30:C$=Z4$
5670 FORI6=1TO41:IFC$=LEFT$(C$(I6),LEN(C$))THENPL=I6:C$=C$(I6):GOTO5700
5680 NEXTI6
5690 PRINT"ILLEGAL GROUP":GOTO5660
5700 PRINT"# PROPERTY";TAB(30);"OWNER"
5710 HO=0:CT=0:FORI=PLTOPL+4:IFC$=C$(I)THENCT=CT+1:PRINTCT" "PN$(I)"";TAB(35);PS(I)
5720 IFH(I)THENHO=1
5730 NEXT
5740 PRINT:PRINT"WHAT NUMBER DOES PLAYER"P1"WANT TO SELL"
5750 GOSUB30:TP=VAL(Z4$)
5760 CT=0:FORI=PLTOPL+4:IFC$=C$(I)THENCT=CT+1:IFCT=TPTHENT4=I:FF=1
5770 NEXT
5780 IFFF=0THENPRINT"ILLEGAL NUMBER":GOTO5740
5790 IFPS(T4)<>P1THENPRINT"PLAYER #"P1"DOES NOT OWN IT.":GOTO5610
5800 IFHOTHENPRINT"YOU HAVE HOUSES ON THAT GROUP YOU CAN'T SELL IT.":GOTO5840
5810 PRINT"WHAT IS THE AGREED SELLING PRICE";:GOSUB30:SP=VAL(Z4$)
5820 M(P1)=M(P1)+SP:M(P2)=M(P2)-SP:PS(T4)=P2
5830 PRINT"PLAYER #"P2"BOUGHT "PN$(T4)"":PRINT"FOR $"SP
5840 PRINT:GOSUB2100:RETURN
5850 PRINT"PROPERTY";TAB(30);"OWNER"
5860 FORI=6TO36STEP10:N=N+1:PRINTN" "PN$(I)"";TAB(35);PS(I):NEXT:N=0
5870 PRINT" 5 "PN$(13)"";TAB(35);PS(13):PRINT" 6 "PN$(29)"";TAB(35);PS(29)
5880 PRINT"WHICH #";:GOSUB30:NM=VAL(Z4$):IFNM=0THENRETURN
5890 IFNM<1ORNM>6THEN5880
5900 IFNM=5ANDPS(13)=P1THENSN=13:GOTO5940
5910 IFNM=6ANDPS(29)=P1THENSN=29:GOTO5940
5920 IFNM>0ANDNM<5THENSN=6+((NM-1)*10):IFPS(SN)=P1THENGOTO5940
5930 PRINT"YOU DON'T OWN IT.":GOTO5850
5940 PRINT"AGREED PRICE";:GOSUB30:SP=VAL(Z4$)
5950 M(P1)=M(P1)+SP:M(P2)=M(P2)-SP:PS(SN)=P2
5960 GOSUB2100:RETURN
5970 PRINT"[147]":PRINT" OPTIONS":PRINT"0 RETURN TO MAIN MENU":PRINT"1 MORTAGE PROPERTY"
5980 PRINT"2 MORTAGE RAILROAD":PRINT"3 MORTAGE UTILITY"
5990 PRINT"4 LIFT MORTAGE(AT 10% INTEREST)":PRINT"5 SELL HOUSES":PRINT
6000 PRINT"CHOICE";:GOSUB30:GG=VAL(Z4$):IFGG<0ORGG>5THEN6000
6010 IFGG=0THENGOSUB2100:RETURN
6020 ONGGGOSUB6040,6270,6360,6440,7070
6030 GOTO5970
6040 PRINT:PRINT"ON WHICH GROUP IS THE PROPERTY TO BE":PRINT"MORTAGED LOCATED?":PRINTPG$
6050 PRINT:PRINT"COLOR GROUP";:GOSUB30:C$=Z4$
6060 FORI6=1TO41:IFC$=LEFT$(C$(I6),LEN(C$))THENPL=I6:C$=C$(I6):GOTO6090
6070 NEXTI6
6080 PRINT"ILLEGAL GROUP":GOTO6050
6090 CM=0:FORI=PLTOPL+3:IFC$=C$(I)THENCM=CM+H(I)
6100 NEXT
6110 IFCMTHENPRINT"CAN'T MORTAGE PROPERTIES WITH HOUSES STILL ON THAT GROUP.":GOTO6260
6120 PRINT"# PROPERTY";TAB(25);"OWNER"
6130 CT=0:FORI=PLTOPL+4:IFC$<>C$(I)THEN6160
6140 CT=CT+1:PRINTCT" "PN$(I)"";TAB(27)PS(I);:PP$="":IFMG(I)THENPP$="MORTAGED"
6150 PRINTPP$
6160 NEXT
6170 PRINT:PRINT"WHAT NUMBER IS TO BE MORTAGED.";:GOSUB30:TP=VAL(Z4$)
6180 IFTP=0THENGOSUB2100:RETURN
6190 CT=0:FORI=PLTOPL+4:IFC$=C$(I)THENCT=CT+1:IFCT=TPTHENT4=I:FF=1
6200 NEXT
6210 IFFF=0THENPRINT"ILLEGAL NUMBER":GOTO6170
6220 IFPS(T4)<>PTTHENPRINT"YOU DON'T OWN IT.":GOSUB2100:GOTO5970
6230 IFMG(T4)=1THENPRINT"ALREADY MORTAGED":GOTO6170
6240 PRINT:PRINT"OK":MG(T4)=1
6250 PRINT"YOU GOT $"P(T4,8)"FOR YOUR MORTAGE.":M(PT)=M(PT)+P(T4,8)
6260 GOSUB2100:RETURN
6270 RC=0:FORI=6TO36STEP10:IFPT$(I)="RR"THENRC=RC+1:PRINTRC" "PN$(I)" PLR.#"PS(I)
6280 NEXT
6290 PRINT"WHICH #";:GOSUB30:RG=VAL(Z4$)
6300 IFRG<1ORRG>4THEN6290
6310 RG=6+((RG-1)*10)
6320 IFPS(RG)<>PTTHENPRINT"YOU DON'T OWN IT.":GOSUB2100:GOTO5970
6330 IFMG(RG)=1THENPRINT"ALREADY MORTAGED.":GOSUB2100:GOTO5970
6340 MG(RG)=1:PRINT"YOU GET $100 FOR MORTAGE.":M(PT)=M(PT)+100
6350 GOSUB2100:RETURN
6360 U(1)=13:U(2)=29
6370 FORI=1TO2:PRINTI" "PN$(U(I))"":NEXT
6380 PRINT"WHICH?";:GOSUB30:UM=VAL(Z4$)
6390 IFUM<1ORUM>2THEN6380
6400 IFPS(U(UM))<>PTTHENPRINT"YOU DON'T OWN IT.":GOSUB2100:GOTO5970
6410 IFMG(U(UM))=1THENPRINT"ALREADY MORTAGED.":GOSUB2100:GOTO5970
6420 MG(U(UM))=1:PRINT"YOU GET $75 FOR MORTAGE.":M(PT)=M(PT)+75
6430 GOSUB2100:RETURN
6440 PRINT:PRINT"THESE ARE THE PROPERTIES THAT ARE UNDER A MORTAGE."
6450 ML=0:FORI=1TO41:IFPS(I)=(PT)ANDMG(I)=1THENML=ML+1:PRINTML" "PN$(I)""
6460 NEXT
6470 IFML=0THENPRINT"YOU HAVE NO MORTAGED PROPERTIES.":GOSUB2100:RETURN
6480 PRINT:PRINT"WHICH MORTAGE DO YOU WAN'T TO LIFT";:GOSUB30:LF=VAL(Z4$)
6490 IFLF<1ORLF>MLTHENPRINT"ILLEGAL":GOTO6480
6500 ML=0:FORI=1TO41:IFPS(I)=(PT)ANDMG(I)=1THENML=ML+1:IFML=LFTHENFT=I
6510 NEXT
6520 PRINT"THE MORTAGE IS FOR $"P(FT,8)
6530 PRINT"YOU MUST PAY $";:PY=P(FT,8)*1.10:PRINTPY
6540 IFPY>M(PT)THENPRINT"YOU DON'T HAVE THE MONEY.":GOSUB2100:RETURN
6550 M(PT)=M(PT)-PY:MG(FT)=0
6560 GOSUB2100:RETURN
6570 IFAFTHEN6590
6580 RETURN
6590 PL=PL(PT):PRINTPN$(PL)" WILL NOW BE AUCTIONED"
6600 PRINT"TO THE HIGHEST BIDDER"
6610 PO=3-PT:PRINT:HB=0:PA=PT:AC=0:PRINT:HB=0:PA=PT:AC=0
6620 PA=3-PA
6630 PRINT"PLAYER"PA"WHAT'S YOUR BID";:GOSUB30:BD=VAL(Z4$):BD=INT(BD):AC=AC+1
6640 IFBD=0THENON(AC>1)+2GOTO6670,6620
6650 IFBD<=HBTHENPRINT"YOU MUST BID HIGHER THAN"HB"OR BID '0'":GOTO6630
6660 HB=BD:HR=PA:GOTO6620
6670 IFHB=0THEN6720
6680 PRINTPN$(PL)" GOES TO"
6690 PRINT"PLAYER"HR" FOR $"HB
6700 M(HR)=M(HR)-HB:PS(PL)=HR
6710 RETURN
6720 PRINT:PRINTPN$(PL)" HAS NOT BEEN PURCHASED.":RETURN
6730 PRINT"[147]":PRINT"PLAYER #"PT"IS BROKE!!"
6740 PRINT"IF YOU CAN'T RAISE $"ABS(M(PT))"THEN YOU ARE OUT OF THE GAME."
6750 PRINT"DO NOT HIT 'Q' (RETURN TO GAME) UNTIL YOU FINISH TRYING TO";
6760 PRINT" RAISE MONEY"
6770 GOSUB2100:GOSUB4580
6780 IFM(PT)>=0THENRETURN
6790 IFM(PT)<0THENPRINT"YOU ARE BANKRUPT!!!":PT=3-PT
6800 PRINT" --PLAYER #"PT"WINS!-- ":END
6810 PRINT"GAME OVER"
6820 PRINT"THE WINNER IS ";
6830 IFM(1)>M(2)THENPRINT"PLAYER #1 WITH $"M(1)
6840 IFM(2)>M(1)THENPRINT"PLAYER #2 WITH $"M(2)
6850 IF M(2)=M(1)THENPRINT"NEITHER, IT'S A TIE!"
6860 PRINT"PLAYER 1 = $";M(1)
6870 PRINT"PLAYER 2 = $";M(2)
6880 PRINT:CLOSE2
6890 POKE54296,0:FORI=1TO6:POKEG(I),0:END
6900 FORJ=832TO939
6910 READI:POKEJ,I:NEXT
6920 DATA 160,0,185,0,4,153,0,192,185,0,5,153,0,193,185,0,6,153,0
6930 DATA 194,185,0,7,153,0,195,185,0,216,153,0,196,185,0,217,153,0
6940 DATA 197,185,0,218,153,0,198,185
6950 DATA 0,219,153,0,199,200,208,205,96,160,0,185,0,192,153,0,4,185,0,193,153
6960 DATA 0,5,185,0,194,153,0,6,185,0,195,153,0,7,185,0,196,153,0,216,185,0,197
6970 DATA 153,0,217,185,0,198,153,0,218,185,0,199,153,0,219,200,208,205,96
6980 RETURN
6990 FORP4=1TO2
7000 Y$=""+PN$(PL(P4))+LEFT$(" ",18-(LEN(PN$(PL(P4)))-2))+"[146]"
7010 MN$="$"+MID$(STR$(M(P4)),2)+" [146]":X=13:Y=2*P4+3:Z$=Y$:GOSUB1890
7020 Y=Y+1:Z$=MN$:GOSUB1890:NEXT:RETURN
7030 PRINT"DISPLAY DEEDS FOR WHICH COLOR GROUP:":PRINTPG$:GOSUB30:C$=Z4$:PRINT
7040 P3=PL:FORI=1TO41:IFC$=LEFT$(C$(I),LEN(C$))THENGF=1:PL=I:GOSUB2270:GF=0
7050 NEXT:PL=P3:RETURN
7060 M(PT)=M(PT)+200:PRINT"COLLECTED $200":RETURN
7070 PRINT"ON WHICH COLOR GROUP:":PRINTPG$:GOSUB30:C$=Z4$
7080 PL=0:FORI=41TO1STEP-1:IFC$=LEFT$(C$(I),LEN(C$))THENPL=I:C$=C$(I)
7090 NEXTI:IFPLTHEN7110
7100 PRINT"ILLEGAL GROUP":GOTO7070
7110 DO=0:HN=0:FORI=PLTOPL+3:IFPS(I)<>(PT)ANDC$=C$(I)THENDO=1
7120 IFC$=C$(I)THENHN=HN+H(I)
7130 NEXT
7140 IFDO=1ORHN=0THENPRINT"YOU DON'T OWN HOUSES ON THESE PROPERTIES":GOSUB2100:RETURN
7150 PRINT"# PROPERTY";TAB(25);"HOUSES(5=HOTEL)"
7160 CT=0:FORI=PLTOPL+3:IFC$=C$(I)THENCT=CT+1:PRINTCT" "PN$(I)"";TAB(27)H(I)
7170 NEXT
7180 PRINT"WANT TO REMOVE ALL THESE HOUSES";:GOSUB30:A$=Z4$:IFLEFT$(A$,1)="Y"THEN7320
7190 PRINT:PRINT"WHAT # TO REMOVE A HOUSE FROM.";:GOSUB30:TP=VAL(Z4$)
7200 IFTP=0THEN RETURN
7210 CT=0:FORI=PLTOPL+3:IFC$=C$(I)THENCT=CT+1:IFCT=TPTHENT4=I:FF=1
7220 NEXT
7230 IFFF=0THENPRINT"ILLEGAL NUMBER":GOTO7190
7240 IFH(T4)=0THENPRINT"NO HOUSES THERE.":GOTO7190
7250 NN=0:NH=H(T4):FORI=PLTOPL+3:IFH(I)>NHTHENNN=1
7260 NEXT
7270 IFNNTHENPRINT"YOU CAN'T REMOVE THAT HOUSE.":GOTO7190
7280 PRINT:PRINT"OK.":H(T4)=H(T4)-1
7290 HM=P(PL,9)/2
7300 PRINT"YOU GOT $"HM"FOR YOUR HOUSE":M(PT)=M(PT)+HM
7310 GOSUB2100:GOTO5970
7320 HM=0:FORI=PLTOPL+3:IFC$=C$(I)THENHM=HM+(P(PL,9)/2)*H(I):H(I)=0
7330 NEXT:PRINT"YOU GOT $"HM"FOR YOUR HOUSES":M(PT)=M(PT)+HM:GOTO7310